<?xml version="1.0"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" creationComplete="startRotation()" >
<mx:Script>
<![CDATA[
private var thread:PseudoThread;
private var bmd:BitmapData;

private function launchThread():void 
{
	bmd = Bitmap(foo.content).bitmapData.clone();
	
	thread = new PseudoThread(systemManager, colorRowOfPixels, { curY: 0, maxY: bmd.height, maxX: bmd.width });
	thread.addEventListener("threadComplete", threadCompleteHandler);
}

private function colorRowOfPixels(obj:Object):Boolean
{
	trace("colorit");
	var yy:int = obj.curY;
	var maxX:int = obj.maxX;
	
	for (var xx:int = 0; xx < maxX; xx++)
	{
		var pix:uint = bmd.getPixel32(xx, yy);
		if (pix)
		{
			var red:uint = pix >> 16 & 0xff;
			if (red < 0xff)
				red = Math.min(red + 15, 0xff);
			pix = (red << 16 & 0xff0000) + (pix & 0xff00ffff);
			bmd.setPixel32(xx, yy, pix);
		}
	}
	obj.curY++;
	return (obj.curY < obj.maxY);
}

private function threadCompleteHandler(event:Event):void
{
	var bm:Bitmap = new Bitmap();
	bm.bitmapData = bmd;
	bar.source = bm;
}

private function startRotation():void
{
	addEventListener("enterFrame", enterFrameHandler);
}

private function enterFrameHandler(event:Event):void
{
	trace("enterFrame");
	but.rotation += 4;
}

]]>
</mx:Script>
<mx:HBox>
<mx:Image id="foo" scaleContent="false" source="assets/Nokia_6630.png" complete="callLater(launchThread)" />
<mx:Image id="bar" />
</mx:HBox>
<mx:Button id="but" />
</mx:Application>